#define MyAppName "固定资产打印助手"
#ifndef MyAppVersion
  #define MyAppVersion "0.2.5"
#endif
#define MyAppPublisher "常州简尚家具有限公司"
#define MyAppExeName "FixedAssetPrintAgent.exe"
#define MyAppId "com.jsgdzc.printagent.dotnet"
#define MyAppSourceDir "..\dist\publish\win-x64"
#define MyAppOutputDir "..\dist\installer"

[Setup]
AppId={#MyAppId}
AppName={#MyAppName}
AppVersion={#MyAppVersion}
AppPublisher={#MyAppPublisher}
AppPublisherURL=https://www.jsgdzc.cn
DefaultDirName={localappdata}\Programs\{#MyAppName}
DefaultGroupName={#MyAppName}
DisableProgramGroupPage=yes
PrivilegesRequired=lowest
Compression=lzma2/max
SolidCompression=yes
WizardStyle=modern
ArchitecturesAllowed=x64compatible
ArchitecturesInstallIn64BitMode=x64compatible
UninstallDisplayIcon={app}\{#MyAppExeName}
AppMutex=Jsgdzc.FixedAssetPrintAgent
CloseApplications=yes
CloseApplicationsFilter={#MyAppExeName}
RestartApplications=no
OutputDir={#MyAppOutputDir}
OutputBaseFilename=print-agent-setup-{#MyAppVersion}

[Languages]
Name: "chinesesimp"; MessagesFile: "compiler:Default.isl,ChineseSimplified.isl"

[CustomMessages]
chinesesimp.InstallationRunningHint=如果看到“打印助手正在运行”的提示，保持“自动关闭应用程序”即可，安装程序会先关闭旧版助手，再继续覆盖安装。

[Tasks]
Name: "desktopicon"; Description: "创建桌面快捷方式"; GroupDescription: "附加图标："; Flags: unchecked

[Files]
Source: "{#MyAppSourceDir}\{#MyAppExeName}"; DestDir: "{app}"; Flags: ignoreversion

[Icons]
Name: "{group}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"
Name: "{group}\卸载 {#MyAppName}"; Filename: "{uninstallexe}"
Name: "{autodesktop}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"; Tasks: desktopicon

[Run]
Filename: "{app}\{#MyAppExeName}"; Description: "立即启动 {#MyAppName}"; Flags: nowait postinstall skipifsilent

[Code]
procedure InitializeWizard();
begin
  WizardForm.WelcomeLabel2.Caption :=
    WizardForm.WelcomeLabel2.Caption + #13#10#13#10 +
    CustomMessage('InstallationRunningHint');
end;